网站建设
联系我们

dbms_scheduler调度

发布于:2014-02-11 14:34来源:未知 作者:admin 点击:
1.作业(job):
 
  一个调度程序作业的实体.可以由dbms_scheduler.create_job创建生成.它可以自行指定作业属性,也可以调用我们预先创建的一系列scheduler/ program/ chain/ job_class/ window/ window_group来匹配其作业属性.
begin
  dbms_scheduler.create_job
  (
  job_name => 'ARC_MOVE',
    repeat_interval => 'FREQ=MINUTELY; INTERVAL=30',
--schedule_name => 'EVERY_60_MINS',
  job_type => 'EXECUTABLE',
  job_action => '/home/dbtools/move_arcs.sh',
  enabled => true,
  comments => 'Move Archived Logs to a Different Directory'
  );
  end;
  /
 
 
2.调度(scheduler):
 
  一个任务计划执行的时间策略.比如我们想要创建一个晚上3点执行的任务计划,就可以创建一个调度,凡是符合这个调度要求的,都可以调用这个我们预先创建好的调度.可以用dbms_scheduler.create_schedule来创建一个调度.
 
  比如我创建一个名字叫MYTEST_SCHEDULE的调度,每天4:00执行.
Begin
  dbms_scheduler.create_schedule(
   repeat_interval => 'FREQ=DAILY;BYHOUR=4;BYMINUTE=0;BYSECOND=0',
  start_date => systimestamp at time zone 'PRC',
   comments => '---this is my test schedule---',
  schedule_name => 'MYTEST_SCHEDULE');
  end;
/
 
如果我们创建了一个job,并且希望它按照我们指定的日期和时间来运行,就需要定义job的重复频度了. 例如每天运行,每周日的22:00运行, 每周一,三,五运行,每年的最后一个星期天运行等等.
  (说明:10G以前的版本,与操作系统的交互方面,实现的不是很好。例如要实现一个定期的rman备份任务,就需要结合OS的命令来实现,在UNIX下可以用crontab实现,在windows下用AT命令来实现)
  10G 在这方面有了很大的增强,因为创建job时可以直接指定操作系统的命令或者脚本,再合理的定义job的执行频率,可以很轻松地完成复杂的调度任务.
  10G 支持两种模式的repeat_interval,一种是PL/SQL表达式,这也是dbms_job包中所使用的,例如SYSDATE+1, SYSDATE + 30/24*60; 另一种就是日历表达式。
  例如MON表示星期一,SUN表示星期天,DAY表示每天,WEEK表示每周等等. 下面来看几个使用日历表达式的例子:
repeat_interval => 'FREQ=MINUTELY; INTERVAL=30'    每30分钟运行
repeat_interval => 'FREQ=HOURLY; INTERVAL=2' 每隔2小时运行一次job
repeat_interval => 'FREQ=DAILY'  每天运行一次job
repeat_interval => 'FREQ=WEEKLY; BYDAY=MON,WED,FRI"  每周的1,3,5运行job
repeat_interval => 'FREQ=YEARLY; BYMONTH=MAR,JUN,SEP,DEC; BYMONTHDAY=30'  每年的3,6,9,12月的30号运行job
用过crontab的人应该都有种似曾相识的感觉吧,呵呵
日历表达式基本分为三部分: 
第一部分是频率,也就是"FREQ"这个关键字,它是必须指定的; 
第二部分是时间间隔,也就是"INTERVAL"这个关键字,取值范围是1-999. 它是可选的参数; 
最后一部分是附加的参数,可用于精确地指定日期和时间,它也是可选的参数,例如下面这些值都是合法的:
 
BYMONTH,BYWEEKNO,BYYEARDAY,BYMONTHDAY,BYDAY,BYHOUR,BYMINUTE,BYSECOND
 
既然说到了repeat_interval,你可能要问:"有没有一种简便的方法来得出,或者说是评估出job的每次运行时间,以及下一次的运行时间呢?"
  dbms_scheduler包提供了一个过程evaluate_calendar_string,可以很方便地完成这个需求. 来看下面的例子:
SQL> set serveroutput on size 999999
declare
L_start_date TIMESTAMP;
l_next_date TIMESTAMP;
l_return_date TIMESTAMP;
begin
l_start_date := trunc(SYSTIMESTAMP);
l_return_date := l_start_date;
for ctr in 1..10 loop
dbms_scheduler.evaluate_calendar_string(
'FREQ=DAILY; BYDAY=MON,TUE,WED,THU,FRI; BYHOUR=7,15',
l_start_date, l_return_date, l_next_date
);
dbms_output.put_line('Next Run on: ' ||
to_char(l_next_date,'mm/dd/yyyy hh24:mi:ss'));
l_return_date := l_next_date;
end loop;
end;
/
 
3.程序(program):
 
  10g下的program支持分为3种形式,PL/SQL BLOCK/STORED PROCEDURE/EXECUTABLE.可以使用DBMS_SCHEDULER.CREATE_PROGRAM来创建一个program.
 
BEGIN
  DBMS_SCHEDULER.CREATE_PROGRAM(
   program_name=>'mytest_program_1',
   program_action=>'update mytest set id=id+1;',
  program_type=>'PLSQL_BLOCK',
  number_of_arguments=>0,
  comments=>'',
   enabled=>TRUE);
  END;
/
 
4.链(chain):
 
  链可以看作是一个/几个program/event scheduler的集合,为了维护需要,我们可能需要将很多不同的program放到一起依次执行,按照以前的模式,要么将这几个program能整合成一个大的整体,要么分开几个job来单独执行,这无疑加重了维护负担,而chain的出现,可以优化这个问题,我们将实现定义好的program集合到一起,然后统一制定一个job来执行,可以使用dbms_scheduler.create_chain来创建一个chain.
 
  比如,在我的系统中,我分别创建了一个EXECUTABLE类型的和一个STORED PROCEDURE类型的program,我需要他们顺次执行,于是我可以这么做:
 
BEGIN
  dbms_scheduler.create_chain( chain_name =>'MYTEST_CHAIN');
  dbms_scheduler.define_chain_step(chain_name =>'MYTEST_CHAIN', step_name =>'mytest_chain_1',program_name =>'P_1');
   dbms_scheduler.alter_chain(chain_name =>'MYTEST_CHAIN', step_name =>'mytest_chain_1',attribute=>'skip',value=>FALSE);
   dbms_scheduler.define_chain_step(chain_name =>'MYTEST_CHAIN',step_name =>'mytest_chain_2',program_name =>'P_2');
   dbms_scheduler.alter_chain(chain_name =>'MYTEST_CHAIN',step_name =>'mytest_chain_2',attribute=>'skip', value=>FALSE);
  dbms_scheduler.enable('MYTEST_CHAIN');
   END;
/
 
4.作业类(job_class):
 
  定义了运行作业的资源使用者组.通过使用窗口中的资源计划,我们可以在不同资源组和不同作业类之间分配资源.可以使用 dbms_scheduler.create_job_class创建一个作业类.
BEGIN
  dbms_scheduler.create_job_class(
   logging_level => DBMS_SCHEDULER.LOGGING_RUNS,
   log_history => 100,
   resource_consumer_group => 'AUTO_TASK_CONSUMER_GROUP',
   job_class_name => 'MYTEST_JOB_CLASS');
  END;
/
 
5.窗口(window):
 
  可以看成是一个更高功能的调度,窗口可以调用系统中存在的调度(也可以自行定义执行时间),而且,具有资源计划限制功能,窗口可以归属于某个窗口组.
 
  可以使用DBMS_SCHEDULER.CREATE_WINDOW来创建一个窗口.
 
  例如我创建了一个名为mytest_windows_1的窗口,采用DAILY_PURGE_SCHEDULE的调度方式,资源计划限制方案为 SYSTEM_PLAN,持续时间为4小时.
 
BEGIN
  DBMS_SCHEDULER.CREATE_WINDOW(
   window_name=>'mytest_windows_1',
   resource_plan=>'SYSTEM_PLAN',
   schedule_name=>'SYS.DAILY_PURGE_SCHEDULE',
   duration=>numtodsinterval(240, 'minute'),
   window_priority=>'LOW',
  comments=>'');
  END;
/
 
6.窗口组(window_group):
 
  一个/几个窗口的集合.10g默认的自动采集统计信息的调度就是一个窗口组的形式,譬如,设置两个窗口,窗口一指定任务周日-----周五,晚上12点执行,而窗口二设定周六凌晨3点执行,这两个窗口组成了一个窗口组,形成了这个job的执行调度策略.
 
  可以使用DBMS_SCHEDULER.CREATE_WINDOW_GROUP来创建一个窗口组.
BEGIN
  DBMS_SCHEDULER.CREATE_WINDOW_GROUP(
   group_name=>'mytest_window_group',
   window_list=>'MYTEST_WINDOWS_1,WEEKEND_WINDOW');
  END;
/
 
于是,使用dbms_scheduler创建一个job,我们可以调用各种预先定义的复杂属性,也可以简单的手动约定各个需要的属性.
 
  简单的,如
BEGIN
  dbms_scheduler.create_job(
   job_name => ' MYTEST_JOB_1',
  job_type => 'PLSQL_BLOCK',
  job_action => 'update mytest set id=id+1;',
   repeat_interval => 'FREQ=MINUTELY;INTERVAL=10',
   start_date => sysdate,
  auto_drop => FALSE,
   enabled => TRUE);
  END;
/
跟采用dbms_job并不太大区别,只是repeat_interval等语法上有差别.
  复杂点的,如:
BEGIN
  dbms_scheduler.create_job(
   job_name => 'MYTEST_JOB_2',
  job_type => 'CHAIN',
   job_action => 'MYTEST_CHAIN',
   schedule_name => 'SYS.MYTEST_WINDOW_GROUP',
   job_class => 'DEFAULT_JOB_CLASS',
  auto_drop => FALSE,
   enabled => FALSE);
   dbms_scheduler.set_attribute( name => 'MYTEST_JOB_2', attribute => 'stop_on_window_close', value => FALSE);
  END;
/
 
相关的表/视图:
SQL> select VIEW_NAME from dba_views a where a.view_name like 'DBA_SCHEDULER%';
  VIEW_NAME
  ------------------------------
  DBA_SCHEDULER_PROGRAMS
   DBA_SCHEDULER_JOBS
  DBA_SCHEDULER_JOB_CLASSES
   DBA_SCHEDULER_WINDOWS
  DBA_SCHEDULER_PROGRAM_ARGS
   DBA_SCHEDULER_JOB_ARGS
  DBA_SCHEDULER_JOB_LOG
   DBA_SCHEDULER_JOB_RUN_DETAILS
  DBA_SCHEDULER_WINDOW_LOG
   DBA_SCHEDULER_WINDOW_DETAILS
  DBA_SCHEDULER_WINDOW_GROUPS
   DBA_SCHEDULER_WINGROUP_MEMBERS
  DBA_SCHEDULER_SCHEDULES
   DBA_SCHEDULER_RUNNING_JOBS
  DBA_SCHEDULER_GLOBAL_ATTRIBUTE
   DBA_SCHEDULER_CHAINS
  DBA_SCHEDULER_CHAIN_RULES
   DBA_SCHEDULER_CHAIN_STEPS
  DBA_SCHEDULER_RUNNING_CHAINS
tag标签:
------分隔线----------------------------
------分隔线----------------------------